当前位置:首页 > 编程学习 > VS Code配置用批处理编译C++

VS Code配置用批处理编译C++

编程学习2022-06-0239030

在VS Code中使用批处理编译的配置

用批处理单独处理编译程序,可以很方便的在VSCode,Editplus,Sublime Text等软件里配置编译功能。


使用VS 2022编译

从VS2015开始使用这个批处理,版本升级后只需要把VS的本机工具命令路径修改一下。


把下面内容保存为vc2022.bat

@echo off

rem =============================
REM  Visual C++ 2022 编译批处理
rem =============================
rem
rem 调用参数 : "$(FilePath)" 
rem
rem "$(FilePath)" 	编译文件路径
rem

rem SETLOCAL 开始批处理文件中环境改动的本地化操作
SETLOCAL

cd /d "%~dp1"

set OUTDIR=%~dp1exeOut
set FILE=%~n1

set EXT=%~x1
if /I "%EXT%" NEQ ".cpp" (
    if /I "%EXT%" NEQ ".c" (	
    	echo 文件类型错误!
    	goto END
    )
)
 
rem 切换到 VS2022 本机工具命令提示 再进行编译
call "C:\Program Files\Microsoft Visual Studio\2022\Professional\VC\Auxiliary\Build\vcvars64.bat" > NUL

echo     Visual C++ 2022 编译 %1 ...
echo --------------------------------------------------------------------------------

@if NOT EXIST "%OUTDIR%" (
    echo.
    echo 输出目录不存在,创建输出目录 "%OUTDIR%" ...
    md "%OUTDIR%"
)

rem 编译选项 
set CL=/MP /GS /analyze- /W3 /Gy  /Zc:wchar_t /Gm- /Od /fp:precise /D "WIN32" /D "_DEBUG" /D "DEBUG" /D "_CONSOLE"  /D "_UNICODE" /D "UNICODE"  /errorReport:prompt /WX- /Zc:forScope /Gd /Oy- /Oi /MD /Fe"%OUTDIR%/" /EHsc /nologo /Fo"%OUTDIR%/"  /Fp"%OUTDIR%/" /Fd"%OUTDIR%/" /ZI

echo.
echo cl.exe %* %CL% ...

cl.exe %* %CL%  user32.lib gdi32.lib kernel32.lib winspool.lib comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib odbc32.lib odbccp32.lib 

SET RETURN=%ErrorLevel%

echo.
if %RETURN% == 0 (
    echo 编译成功!
) else (
    echo 编译失败,请检查错误!
)

echo.
echo 清理垃圾文件 ...
@if EXIST "%OUTDIR%\%FILE%.obj" (del "%OUTDIR%\%FILE%.obj")
@if EXIST "%OUTDIR%\%FILE%.?db" (del "%OUTDIR%\%FILE%.?db")

rem 编译成功后直接运行程序,vscode可以不用,像editplus、Sublime Text可以取消注释
rem if %RETURN% == 0 (
rem     CD /d "%OUTDIR%"
rem     echo.
rem     echo 正在启动程序 %OUTDIR%\%FILE%.exe...
rem     START %OUTDIR%\%FILE%.exe
rem )

:END

rem ENDLOCAL  结束批处理文件中环境改动的本地化操作
ENDLOCAL


使用VC6编译

使用这个批处理不需要把vc添加到path中。

把下面内容保存为vc6.bat

@echo off

rem =============================
REM  VC++ 6 编译批处理
rem =============================
rem	
rem 调用参数 : "$(FilePath)" -S
rem 
rem "$(FilePath)" 	编译文件路径
rem -S	可选,不链接,只编译输出汇编文件.cod
rem

rem SETLOCAL 开始批处理文件中环境改动的本地化操作
SETLOCAL

cd /d "%~dp1"

set OUTDIR=%~dp1exeOut
set FILE=%~n1

set EXT=%~x1
if /I "%EXT%" NEQ ".cpp" (
	if /I "%EXT%" NEQ ".c" (	
		echo 文件类型错误!
		goto END
	)
)

rem 修改为你机子上VC的路径
CALL E:\Apull\Program\VC6\VC98\Bin\VCVARS32.BAT > nul

echo     VC++ 6.0 编译 %1 %2...
echo --------------------------------------------------------------------------------

@if NOT EXIST "%OUTDIR%" (
	echo.
    echo 输出目录不存在,创建输出目录 "%OUTDIR%" ...
    md "%OUTDIR%"
)


set CL=/nologo /MD /W3 /Ox /EHsc /GX /D "WIN32" /D "NDEBUG" /D "_WINDOWS" /D "_CONSOLE" /D "_UNICODE" /D "UNICODE" /Fo"%OUTDIR%/" /Fe"%OUTDIR%/" /Fd"%OUTDIR%/"


IF "%2" == "-S" ( SET CL=%CL% /FAc /Fa"%OUTDIR%/" /c )

echo.
echo cl.exe %1 %CL%  ...

cl %* %CL%
rem  user32.lib gdi32.lib kernel32.lib winspool.lib comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib odbc32.lib odbccp32.lib easyx*.lib 

SET RETURN=%ErrorLevel%

echo.
if %RETURN% == 0 (
	echo 编译成功!
) else (
	echo 编译失败,请检查错误!
)

echo.
echo 清理垃圾文件 ...
@if EXIST "%OUTDIR%\%FILE%.obj" (del "%OUTDIR%\%FILE%.obj")
@if EXIST "%OUTDIR%\%FILE%.pdb" (del "%OUTDIR%\%FILE%.pdb")

rem 编译成功后直接运行程序
rem IF NOT "%2" == "-S" (
rem 	if %RETURN% == 0 (
rem 		CD /d "%OUTDIR%"
rem 		echo.
rem 		echo 正在启动程序 %OUTDIR%\%FILE%.exe...
rem 		START %OUTDIR%\%FILE%.exe
rem 	)
rem )

:END

rem ENDLOCAL  结束批处理文件中环境改动的本地化操作
ENDLOCAL


使用GCC编译


把下面内容保存为gcc.bat

@echo off

rem =============================
REM  GCC 编译批处理
rem =============================
rem	
rem 调用参数 : "$(FilePath)" 
rem 
rem "$(FilePath)" 	编译文件路径
rem
rem		Apull apull.net

rem SETLOCAL 开始批处理文件中环境改动的本地化操作
SETLOCAL

cd /d "%~dp1"

set OUTDIR=%~dp1exeOut
set FILE=%~n1
set EXT=%~x1

if /I "%EXT%" NEQ ".cpp" (
    if /I "%EXT%" NEQ ".c" (	
        echo 文件类型错误!
        goto END
    )
)

set GCC=G++
set STD=-std=c++11
if /I "%EXT%" == ".c" (
	set GCC=gcc
	set STD=-std=c11 
)

echo.
echo     %GCC% 8.1.0 x64 编译 %1 ...
echo --------------------------------------------------------------------------------

@if NOT EXIST "%OUTDIR%" (
    echo.
    echo 输出目录不存在,创建输出目录 "%OUTDIR%" ...
    md "%OUTDIR%"
)

rem 修改为你的gcc路径
set P=E:\Apull\Program\MinGW

path=%P%\bin;

rem 编译参数
set out=-o"%OUTDIR%\%FILE%.exe"
set var=-Wall -O2 %STD% -fdiagnostics-color=auto
echo.

echo %GCC% %var% %* %out%

call %GCC% %var% %* %out%


echo.
if %ErrorLevel% == 0 (
    echo 编译成功!
) else (
    echo 编译失败,请检查错误!
)

echo.
echo 清理垃圾文件 ...
@if EXIST "%OUTDIR%\*.obj" (del "%OUTDIR%\*.obj")
@if EXIST "%OUTDIR%\*.tds" (del "%OUTDIR%\*.tds")

:END

rem ENDLOCAL  结束批处理文件中环境改动的本地化操作
ENDLOCAL


配置task.json文件

需要修改文件路径为你电脑上的路径

{
    // See https://go.microsoft.com/fwlink/?LinkId=733558
    // for the documentation about the tasks.json format
    "version": "2.0.0",
    "tasks": [
        {
            "label": "g++",
            "type": "shell",
            "command": "E:/Apull/Program/gcc.bat",
            "args": [
                "${file}",
                //"${fileDirname}/*.cpp",
                "-Ofast"
            ]
        },
        {
            "label": "g++debug",
            "type": "shell",
            "command": "E:/Apull/Program/gcc.bat",
            "args": [
                "${file}",
                "-g",
                "-Og"
            ]
        },
        {
            "label": "VC2022",
            "type": "shell",
            "command": "E:/Apull/Program/vc2022.bat",
            "args": [
                "${file}"
            ]
        },
        {
            "label": "VC6",
            "type": "shell",
            "command": "E:/Apull/Program/vc6.bat",
            "args": [
                "${file}"
            ]
        }
    ]
}


运行效果


vc2022.png VS Code配置用批处理编译C++  编程 技术 电脑 C++ VC 第1张

vc6.png VS Code配置用批处理编译C++  编程 技术 电脑 C++ VC 第2张




扫描二维码推送至手机访问。

版权声明:本文由海阔天空发布,如需转载请注明出处。

本文链接:https://www.apull.net/html/20220602125509.html

分享给朋友:

相关文章

密码的故事

密码的故事

密码的故事Billy Hollis 本文是由一个问题引出的。我需要一种将密码保存在加密文件中的方法,因为我需要记住许多密码,但记忆力却已大不如前。我知道有许多商用工具能够做到这一点,但我感到学习  .NET 中的一项新技术真的很有好处。 我用 Visual Basic® .NET  完成了一个简单而完整的程序,用于加密和解密文件,从中学到了许多知识。既然加密对于多种开发都是一个重要问题,本文就介绍一下如何构造这样的程序。 有各种低级别的技术可以用于加密,...

VB.NET中如何扩充字符串进行固定宽度显示

VB.NET中如何扩充字符串进行固定宽度显示

  在VB.NET中,当你需要在控制台显示数据或准备好打印数据时,可能需要调整列宽以显示固定长度的数据。本文介绍了使用String对象的PadLeft方法和PadRight方法扩充字符串以进行固定宽度显示。PadLeft和PadRight方法      PadLeft和PadRight是字符串类的两个方法,可以分别使用它们在字符串的左边和右边填充空格。这两个方法多接受一个代表总长度的整型数,添加的空格数等于填充总长度减去字符串的当前长...

C++实现十进制转换为二进制

C++实现十进制转换为二进制

这个写得有些早了,学习c++是写的。现在看到很多帖子问这个问题,把这个贴上来供大家参考下。/* * FileName: bin.cpp * * 转换十进制为二进制 * * Apull * 2005-12-2 */ #include <iostream> #include <cstdlib> using namespace std; const int size = sizeof(int) *...

VB/VB.net 只允许运行一个实例

VB/VB.net 只允许运行一个实例

VB/VB.net  只允许运行一个实例       by:  Apull  VB中的实现方法VB如何防止程序被重复加载,也就是只允许运行一个实例,一般有2种方法。一,直接用VB提供的APP对象的PrevInstance方法。PrevInstance的返回值为True则说明已经有一个实力在运行。If App.PrevInstance Then Msgbox "已经有一个实例在运行" End if这个...

发表评论

访客

看不清,换一张

◎欢迎参与讨论,请在这里发表您的看法和观点。